About

<#TEMPLATE_INCLUDE_NINEPAGE_ABOUTME#>
  • Feb

    2

    不少应用程序、游戏会需要完完全全全新的外观与字体,示例主题会无法满足需求。这种时候就会需要从零开始创建一个自定义主题(其实我个人还是推荐“扩展示例主题”,或者重构示例主题,示例主题中已经包含了一些组件的布局设置与“防抖动阔值”设置,删除代码比编写代码肯定要快)。

    创建自定义主题类:

    创建一个全新的自定义主题类,需要扩展 StyleNameFunctionTheme 类: 

    package
    {
        public class CustomTheme extends StyleNameFunctionTheme
        {
            public function CustomTheme()
            {
                super();
            }

            private function initialize():void
            {
            }
        }
    }

    添加一个 initialize() 方法,当主题的其它部份可以用的时候填充到这个方法体内。在调用这个方法前,需要先决定资源是如何管理的:资源可以是被动态加载的或静态嵌入的。所以在资源文件没有被全部加载前,不会立即调用这个方法。

    管理资源:

    有两个方法可以管理主题包含的资源, 每个都有自己的优点和缺点,需要选择哪一个视具体的开发情况。

    第1种:静态嵌入资源。

    在编译时嵌入资源方法最简单,这种方法可以直接实例化资源,而不需要侦听等待资源的加载相关的事件。缺点就是它需要更多的内存,在移动开发大型项目时可能会不适用,因为称动设备的内存比较有限,嵌入的资源数量会受到限制,过多的资源被静态嵌入后,启动 APP 有可能会引起一些中低端机型的 APP 闪退或无 响影。所以这种方法只适合小型项目或嵌入的资源比较少的情况。

    在 CustomTheme 类中嵌入纹理集(texture atlas,一个纹理集需要两个文件:一个图像文件与一个 XML 文件):

    [Embed(source="/../assets/images/atlas.png")]
    private static const ATLAS_BITMAP:Class;

    [Embed(source="/../assets/images/atlas.xml",mimeType="application/octet-stream")]
    private static const ATLAS_XML:Class;

    在主题文件中定义一个成员变量持有纹理集(TextureAtlas)的引用: 

    private var atlas:TextureAtlas;

    然后再创建一个 createTextureAtlas() 方法,实例化纹理后保持引用:

    private function createTextureAtlas():void
    {
        var atlasTexture:Texture = Texture.fromEmbeddedAsset( ATLAS_BITMAP );
        var atlasXML:XML = XML( new ATLAS_XML() );
        this.atlas = new TextureAtlas( atlasTexture, atlasXML );
    }

    在 CustomTheme 构造方法中调用 createTextureAtlas() 方法,然后就可以直接调用 initialize()。

    public function CustomTheme()
    {
        super();
        this.createTextureAtlas();
        this.initialize();
    }

    如果主题需要嵌入其它资源,如其它更多的纹理集、位图字体等,都类似,全部需要在 initialize()  方法前实例化它们。

     第2种:运行时动态加载资源。

    Starling 的资源管理类(AssetManager 类)支持运行时动态加载资源文件(可以一次加载多个资源文件),它还提供了把位图自动转换成对应的纹理集或注册位图字体等功能。这种方式最大的好处是同样的资源数量,会比嵌入资源的方式使用更少的内存,这意味着我们可以打包入更多的资源。加载资源的缺点就是代码稍稍复杂一些,因为需要 AssetManager 类在没有加载完资源之前,无法使用它们,所以就需要侦听加载相关的事件。

     在打包 AIR 应用程序时,有时候资源文件不会被自动打包,所以需要检查一下资源是否被打勾了。

     在主题类中定义两个变量,一个用于资源引用,一个用于加载资源:

    private var atlas:TextureAtlas;
    private var assets:AssetManager;

     添加一个 loadAssets() 方法,用于实例化 AssetManager() 和列队需要加载的资源:

    private function loadAssets():void
    {
        this.assets = new AssetManager();
        this.assets.enqueue( "atlas.png" );
        this.assets.enqueue( "atlas.xml" );
        this.assets.loadQueue( this.assets_onProgress );
    }

     在末尾我们调用 AssetManager 对象的 loadQueue() 方法开始加载资源,再加一个回调函数作为参数,可以用于判定资源的加载情况(回调函数的参数是0-1.0之间的 Number 类型):

    private function assets_onProgress( progress:Number ):void
    {
        if( progress < 1.0 )
        {
            return;
        }
        this.atlas = this.assets.getTextureAtlas( "atlas" );
        this.initialize();
        this.dispatchEventWith( Event.COMPLETE );
    }

    当资源加载完成后,就可以从 AssetManager 对象访问资源纹理集了(TextureAtlas 对象),通过 getTextureAtlas() 方法得到纹理集的引用赋值给主题类的实例变量保持引用(纹理集的名称不需要扩展名,所以上面直接写了 atlas,而不是 atlas.png 或 atlas.xml)。

    资源文件加载完成后,立即调用了 initialize() 方法,如果主题文件需要更多的资源文件,都需要在调用 initialize() 之前加载完。

    最后,为了通知应用程序继续执行后面的代码,派发 Event.COMPLETE 事件:

    this.theme = new CustomTheme();
    this.theme.addEventListener( Event.COMPLETE, theme_completeHandler );

     一旦侦听器被调用,应用程序中就可以开始自由的实例化组件了,主题文件会对组件自动设置样式。

    组件样式化:

    一旦资源文件被加载完成,就可以在应用程序中设置组件的样式化相关的函数了。在这些函数中,样式仅仅是直接简单的设置组件的属性。函数体内的代码就跟没有使用主题文件,直接通过“皮肤”设置组件的代码类似。以 Button 为例:

    private function setButtonStyles( button:Button ):void
    {
        button.defaultSkin = new Image( this.atlas.getTexture( "button-up" ) );
        button.downSkin = new Image( this.atlas.getTexture( "button-down" ) );

        button.padding = 20;
        button.gap = 15;

        button.fontStyles = new TextFormat( "_sans"18, 0x333333 );
    }

    在前面的 initialize() 方法体内,调用一个新的 initializeStyleProviders() 方法(下面定义):

    private function initialize():void
    {
        this.initializeStyleProviders();
    }

    initializeStyleProviders() 方法的定义,并设置样式提供程序:

    private function initializeStyleProviders():void
    {
        // button
        this.getStyleProviderForClass( Button ).defaultStyleFunction = this.setButtonStyles;
    }

    getStyleProviderForClass() 方法返回一个 StyleNameFunctionStyleProvider 对象。

    StyleNameFunctionStyleProvider 对象有两个主要功能,它的 defaultStyleFunction 属性会被用于一类组件的默认皮肤(用的最多的情况)。比如上面的样式代码,当我们生成一个按钮时,就会调用 setButtonStyles() 样式化按钮。但有时候一个组件的不同风格在应用中也会出现,比如同样是按钮,可能是特别醒目,用于警告功能。Button.ALTERNATE_STYLE_NAME_DANGER_BUTTON 常量就可以用来定义一个警告按钮。在开发应用时,可以向组件添加此样式名称,以告诉主题应该采用不同的样式:

    button.styleNameList.add( Button.ALTERNATE_STYLE_NAME_DANGER_BUTTON );

    对应的在主题文件内,设置一个新的样式提供程序,一个名为 setDangerButtonStyles() 的方法:

    private function setDangerButtonStyles( button:Button ):void
    {
        button.defaultSkin = new Image( this.atlas.getTexture( "danger-button-up" ) );
        button.downSkin = new Image( this.atlas.getTexture( "danger-button-down" ) );

        button.padding = 20;
        button.gap = 15;

        button.fontStyles = new TextFormat( "_sans"18, 0x333333 );
    }

    在按钮的样式提供者(StyleNameFunctionStyleProvider)调用 setFunctionForStyleName() 方法注册新的样式提供程序:

    this.getStyleProviderForClass( Button )
        .setFunctionForStyleName( Button.ALTERNATE_STYLE_NAME_DANGER_BUTTON, this.setDangerButtonStyles );

     如果一个组件拥有此样式名称,就会调用此 setDangerButtonStyles() 样式提供程序,而不会使用前面的 setButtonStyles() 样式提供程序。

    样式化子组件:

    有一些组件是带有子组件的,子组件也需要样式化皮肤设置。比如,一个 Slider 组件有一个滑块,这个滑块它是一个 Button 组件。像这种子组件可以通过父组件中的样式化名称来定义区别,例如叫 Slider.DEFAULT_CHILD_STYLE_NAME_THUMB,用来显示滑块的缩略图。

    this.getStyleProviderForClass( Button )
        .setFunctionForStyleName( Slider.DEFAULT_CHILD_STYLE_NAME_THUMB, this.setSliderThumbStyles );

    含有子组件的父组件,通常会提供一个设置子组件样式名称的属性,如果需要除默认值以外的其他值。比如一个 Slider 对象,可以设置 customThumbStyleName 属性:

    slider.customThumbStyleName = "custom-thumb";

     然后,我们可以像设置其它新的样式程序一样,在主题文件中使用该自定义样式名称:

    this.getStyleProviderForClass( Button )
        .setFunctionForStyleName( "custom-thumb", this.setSliderThumbStyles );

    设置全局性的默认值:

    某些全局性的属性通常也是通过主题文件设置的。例如在自定义主题文件中,设置 FeathersControl.defaultTextRendererFactory  FeathersControl.defaultTextEditorFactory 决定 TextInput 默认的文本渲染器与编辑器(还有类似模态化的叠加层等设置往往也是全局性的默认值)

    创建一个 initializeGlobals() 方法:

    private function initializeGlobals():void
    {
        FeathersControl.defaultTextRendererFactory = function():ITextRenderer
        {
            return new TextBlockTextRenderer();
        };

        FeathersControl.defaultTextEditorFactory = function():ITextEditor
        {
            return new StageTextTextEditor();
        };
    }

    在 initialize() 方法中,在调用 initializeStyleProviders() 方法前先调用这种全局性的设置方法:

    private function initialize():void
    {
        this.initializeGlobals();
        this.initializeStyleProviders();
    }

    Feb

    1

    在进行移动开发的时候,个人比较推荐“扩展示例主题”,因为一个示例主题全部代码量和资源算在内只有几百KB,相对于一个 AIR SDK 打包移动APP,动则增加几十M 的容量来说,简直就是小意思了,但却能节省大量的时间。Feathers UI 库中提供的示例主题其实已经从设计时就开始考虑了扩展性,所以既便是在桌面开发中也同样推荐,会非常便于后期维护。除非是桌面 Web 型应用,并且对文件大小非常非 常的严格,那么只能从头开始完完全完的自定义一个主题文件

    添加替换的样式函数

    假设 MetalWorksMobileTheme 主题类符合我们大多数需求,但只有少数 UI 需要进行设整,那么就可以扩展 MetalWorksMobileTheme 类:

    package com.example
    {
        import feathers.themes.MetalWorksMobileTheme;

        public class CustomTheme extends MetalWorksMobileTheme
        {
            public function CustomTheme()
            {
                super();
            }
        }
    }

    当首次启动应用时,实例化主题类:

    new CustomTheme();

    然后,在 CustomTheme 类中添加一个 setCustomButtonStyles 方法,为按钮提供不同的皮肤(假设有个按钮需要修改皮肤):

    protected function setCustomButtonStyles( button:Button ):void
    {
        button.defaultSkin = new Quad( 20060, 0xff0000 );
        button.downSkin = new Quad( 20060, 0x000000 );
        button.fontStyles = new TextFormat( "_sans"36, 0xffffff );
        button.padding = 10;
    }

    在它的超类中定义了一个 initializeStyleProviders() 方法,在该方法中所有的全局样式提供者为 Feathers 组件提供了注册,所以通过覆盖该方法可以通知对应类的全局样式提供者。每一个官方示例主题都是类似的结构(如果是第三方提供的主题文件可能会有所不同):

    override protected function initializeStyleProviders():void
    {
        super.initializeStyleProviders()// 别忘了这个

        this.getStyleProviderForClass( Button )
            .setFunctionForStyleName( "custom-button", this.setCustomButtonStyles );
    }

    通过 getStyleProviderForClass() 方法访问 Button 类的全局样式提供者。如果全局样式提供者(global style provider)还没有被创建过,就会自动创建该对象。因为 MetalWorksMobileTheme 类是 StyleNameFunctionTheme 类的子类,通过 getStyleProviderForClass() 方法返一个 StyleNameFunctionStyleProvider 对象,该对象允许开发者将样式名称与方法关联起来,可以为同一类型的组件提供多个皮肤。

    上面例子中调用了 setFunctionForStyleName() 方法,并传了 “custom-button” 作为样式名称,然后将它与 setCustomButtonStyles 方法名关联起来。

    接下来,对按钮的代码进行一些调整:

    var specialButton:Button = new Button();
    specialButton.label = "Special!";
    specialButton.styleNameList.add( "custom-button" );
    this.addChild( specialButton );

    将  “custom-button” 字符串添加到按钮的 styleNameList,现在按钮就会使用前面自定义的 setCustomButtonStyles() 函数来代替 MetalWorksMobileTheme 定义的默认函数。

    在主题文件中为自定义类提供皮肤:

    默认情况下,自定义类会从它的超类继承样式提供程序。如创建了一个自定义的 CustomButton 类继承了 Button 类,子类就会自动使用 Button.globalStyleProvider。如果希望子类拥有和父类类似的外观,那就不需要做什么。

    但是,如果希望子类使用与其父类不同的默认样式提供程序,则需要向组件的类中添加几个属性。 首先,它需要一个静态全局样式提供者:

    public class CustomComponent extends FeathersControl
    {
        public static var globalStyleProvider:IStyleProvider;
    }

     然后需要覆盖 defaultStyleProvider 实例方法:

    override protected function get defaultStyleProvider():IStyleProvider
    {
        return CustomComponent.globalStyleProvider;
    }

    对绝大多数组件,defaultStyleProvider getter 都应该简单的返回静态全局样式提供者。

    默认样式提供者也是可以自定义的,例如,ToggleButton 组件在 ToggleButton.globalStyleProvider 为 null 时就返回 Button.globalStyleProvider:

    override protected function get defaultStyleProvider():IStyleProvider
    {
        if( ToggleButton.globalStyleProvider )
        {
            return ToggleButton.globalStyleProvider;
        }
        return Button.globalStyleProvider;
    }

    类似的,自定义组件也可以从超类获得可替换的默认样式提供者。

    要将自定义组件添加到主题文件,与前面一样,也是通过覆盖 initializeStyleProviders() 方法:

    override protected function initializeStyleProviders():void
    {
        super.initializeStyleProviders()//别忘了这个!

        this.getStyleProviderForClass(CustomComponent).defaultStyleFunction = 
            this.setCustomComponentStyles;
    }

    可以在 StyleNameFunctionStyleProvider 对象上设置 defaultStyleFunction。如果自定义组件有可替换的备用样式,同样可以像前面介绍的那样对 Button 的全局样式提供者使用 setFunctionForStyleName() 方法。

    Feb

    1

    Feathers 主题或者主题文件(themes)是一个类,集中在同一个文件位置实现多个组件的皮肤样式设置与管理。在主题文件中提供的样式是全局的,任何 Feathers 组件初始化的时候,会自动设置样式。在应用开发时使用主题文件是非常容易、方便和有用的,它可以使用相同的样式皮肤化任何组件。如果想要特殊化一个组件的样式,而不同于默认全局的样式,也可以非常方便的从主题文件中“排除”,如果喜欢默认样式,但想有一些微小的调整,都可以轻松实现。

    主题文件并不是必须的,可以通过 Feathers 组件直接逐个的设置每个组件的样式属性。但使用主题文件会带来很大的好处,就是可以将皮肤样式外观的设置集中到一处,而不会影响其它具体的业务逻辑,减少代码混乱。也可以使用预制的主题(样例主题),进行前期的快速功能开发,后期再调换成自己设计的主题,对其余的部份不会有什么影响。

    初始化主题:

    使用 Feathers UI 库中的示例主题 MetalWorksMobileTheme 类为例,在 Starling 的根容器中立即实例化主题:

    import starling.display.Sprite;
    import feathers.themes.MetalWorksMobileTheme;

    public class Main extends Sprite
    {
        public function Main()
        {
            new MetalWorksMobileTheme();
            super();
        }
    }

    实例化主题的代码在 super() 方法前,如有必要情况,主题就可以对根容器也进行皮肤样式化处理(根容器不一定就是直接扩展 Starling 的 Sprite 类,可能就是实现了一个自定义的 Feathers 组件)。

    此后,当 Feathers 组件被 addChild 到舞台时,主题文件就会自动检测添加的组件,自动给组件添加皮肤。

    自定义特定组件实例:

    1、如果使用主题文件,那么最好将样式化相关的代码都放在主题文件内(脱藕性),但也可以在任何组件上自定义样式,以使其与默认的皮肤样式不同。如自定义一个按钮的标签字体样式: 

    var button:Button = new Button();
    button.label = "Click Me";
    button.fontStyles = new TextFormat( "_sans"20, 0x4c4c4c );
    this.addChild(button);

    如上代码,样例按钮的背景皮肤、padding 等会按着主题文件中的样式进行设置,但 fontStyles 会以这个自定义的 starling.text.TextFormat 样式进行设置。

    相比较而言,在旧版本的 Feathers 中,在主题文件外自定义样式有一些麻烦。如上面的代码,这样直接简单的设置样式有可能会被主题文件替换。但从 Feathers 3.1 开始,这样直接设置样式属性不会再和主题文件中的代码冲突。

    2、还有一些情况,某个组件就是不想使用主题文件中的任何样式,是完完全全自定义的。有下面几种方法可以实现:

    a、清除样式提供者。最直接暴力的方法就是将 styleProvider 属性设为 null,告诉组件不使用主题。

    var button:Button = new Button();
    button.styleProvider = null; //不使用主题文件中的代码!
    button.label = "Click Me";
    button.fontStyles = new TextFormat( "_sans"20, 0x4c4c4c );
    button.defaultSkin = new Quad( 10030, 0xcccccc );
    button.padding = 10;
    this.addChild(button);

    当 styleProvider 属性设为 null 时,按钮的所有样式属性如背景纹理、padding、 layouts、字体等等都需要手动设置了,因为它不会再接受主题文件中的样式代码。

    b、使用扩展的自定义样式名称(相对于前面的方法,这是比较推荐的方法)。这通常会涉及到主题类的扩展,将皮肤样式相关的代码集中放在主题文件中,可以让代码更清晰。

    内置的可交替使用的(备用)样式名称(Built-in alternate style names):

    一些组件提供了一组内置的备用样式名称(style names),样式名称可以被添加到 styleNameList 属性中,用以通知主题文件特定实例的皮肤与默认的皮肤应该有所不同。备用的皮肤在不改变组件功能的基础上,用以在视觉上区分组件实例。例如,希望某个按钮比其它按钮更明显,给它一个名为“call-to-action”的样式名称,让主题给它更明显的颜色用以在视觉上区分其它按钮。

    另一个例子,如 GroupedList 组件有一个标准的普通外观皮肤,看起来就像是 List 组件,但它有 headers 与 footers。还有一个 “inset” 样式,控制组中第一个和最后一个项渲染器的外观带有圆角。如果希望观看两种不同的风格样式,可以在 Component Explorer 中浏览 GroupedList 组件。

    Component Explorer 是类似 Feathers 移动版本的组件 DEMO,使用了 MetalWorksMobileTheme 主题。

    备用的样式名称一般是直接在组件定义的类上定义为 public 的静态常量,如 GroupedList 类定义了 ALTERNATE_STYLE_NAME_INSET_GROUPED_LIST 常量。inset 样式就可以被添加到 styleNameList 中,如:

    var list:GroupedList = new GroupedList();
    list.styleNameList.add( GroupedList.ALTERNATE_STYLE_NAME_INSET_GROUPED_LIST );
    this.addChild( list );

    如果正在使用的主题文件没有为组件的备用样式名称提供对应的皮肤,组件并不会因为找不到皮肤而看不到或产生异常,而是主题会自动回退到显示默认的皮肤。主题文件的程序员并不需要编写特别的代码,它已经是主题系统的核心部分。这样只是为了确保开发者在切换不同的主题文件时,可以让组件的功能正常运行,而不产生问题。如果自定义自己的主题文件,确保为每个备用样式名称提供对应的皮肤是最好的做法。

    文件大小警告:

    示例主题文件包含了每个可用的 feathers 组件,这意味着如果使用示例主题文件,所有的羽毛组件不管用到的还是没用到的都将被编译到正在开发的应用中去。如果要保存文件大小,应该考虑修改主题文件的源代码,以删除项目中未使用的所有组件的引用。另一种更好的方式就是完完全全的从头开始创建一个自定义的主题文件

    Feb

    1

    Feathers3 皮肤资料备注

    • 0 Comments
    • Flash Platform

    所有的 Feathers 组件都支持大量的样式属性以允许用户自定义设计。许多组件包含了多个状态的背景皮肤属性,还有不同的布局属性,如 padding、alignment、字体样式等。此外,还有一些组件在移动开发或桌面开发时分别会有不同的选项。

    实际上 Feathers 没有默认皮肤,它鼓励开发者自己开发设计独一无二的皮肤外观。但也为了方便开发者,Feathers 提供了几个不同风格的示例主题,如果有必要或为了方便开发,开发者也可以直接扩展这些示例主题自定义不同的皮肤。

    基本资料:

    所有的皮肤、布局选项、字体样式等其它有用的样式属性,都是以 public 的属性方式提供了 API。自定义样式化的皮肤和布局时就像设置属性一样简单。以一个按钮为例:

    var button:Button = new Button();
    button.label = "Click Me";
    button.defaultSkin = new Quad( 10030, 0xc4c4c4 );
    button.fontStyles = new TextFormat( "Helvetica"20, 0x3c3c3c );
    this.addChild( button );

    这里只是一个基本示例,还有其它更多的布局或图标相关的样式属性,可以参考具体的 API 手册。其中, starling.text.TextFormat 可以为任何 Feathers 组件用于自定义字体样式,无论是使用位图字体、嵌入字体或设备字体等。

    组件有多个状态

    有些组件类似 Button、TextInput 等有多个状态,可以为不同的状态设置不同的皮肤外观。比如通过 setTextureForState() 设置不同状态时的背景皮肤纹理:

    var skin:ImageSkin = new ImageSkin( upTexture );
    skin.setTextureForState( ButtonState.DOWN, downTexture );
    button.defaultSkin = skin;

    传递一个默认皮肤纹理给 ImageSkin 构造函数,然后再通过 setTextureForState() 方法设置不同状态的纹理。如果我们没有为某个状态设置皮肤纹理,那么默认的皮肤纹理就会被使用,比如上面的代码中没有设置 HOVER 状态的皮肤,那么 HOVER 状态时就会显示默认的皮肤纹理。如果要设转上老母一个状态,可能类似的代码如下面这样子:

    var skin:ImageSkin = new ImageSkin( upTexture );
    skin.setTextureForState( ButtonState.DOWN, downTexture );
    skin.setTextureForState( ButtonState.HOVER, hoverTexture );
    skin.setTextureForState( ButtonState.DISABLED, disabledTexture );
    button.defaultSkin = skin;

    和上面设置不同状态的纹理类似,可以通过 setFontStylesForState() 方法设置不同状态的字体样式。

    var upFontStyles:TextFormat = new TextFormat( "Helvetica"20, 0x3c3c3c );
    var downFontStyles:TextFormat = new TextFormat( "Helvetica"20, 0xff0000 );

    button.fontStyles = upFontStyles;
    button.setFontStylesForState( ButtonState.DOWN, downFontStyles );

    如上代码中,fontStyles 是默认的字体样式,而 setFontStylesForState() 方法可以自定义不同状态的字体样式(new 一个 TextFormat 即可)。

    设置子组件的外观皮肤样式:

    一些“复杂的” Feathers 组件会包含其它 Feathers 组件作为子组件。例如一个 Panel 组件,包含了一个 header 对象,像这样的 header 子组件是可以设置样式的,但它的样式属性并不会直接通过父组件直接暴露给开发者。

    样式化一个子组件比较简单的方法是自定义工厂方法,直接返回一个样式化的子组件,如 Panel 的 header 对象是通过 headerFactory 属性的工厂方法创建的:

    var panel:Panel = new Panel();
    panel.headerFactory = function():IFeathersControl
    {
        var header:Header = new Header();
        header.backgroundSkin = new Quad( 20050, 0x3c3c3c );
        header.fontStyles = new TextFormat( "Helvetica"20, 0xd4d4d4 );
        return header;
    };
    this.addChild( panel );

     如果开发者正在使用一个主题( theme) 文件,可能会希望将皮肤样式外观有关的代码都放在主题文件中,那样的话就不推荐使用生成子组件的工厂方法,而应该为子组件创建新的样式名称,然后将代码移动到主题文件中。

    复杂的组件允许开发者自定义子组件的样式名称。在这个 Panel 的例子中,可以设置 customHeaderStyleName 属性,如:

    var panel:Panel = new Panel();
    panel.customHeaderStyleName = "custom-panel-header";
    this.addChild( panel );

     在主题文件中,创建一个对应的方法用于对子组件进行样式化设置:

    private function setCustomPanelHeaderStyles( header:Header ):void
    {
        header.backgroundSkin = new Quad( 20050, 0x3c3c3c );
        header.fontStyles = new TextFormat( "Helvetica"20, 0xd4d4d4 );
    }

     最后“告诉”主题文件,当子组件有自定义的样式名称时,对应的调用哪个方法:

    getStyleProviderForClass( Header ).setFunctionForStyleName( "custom-panel-header", setCustomPanelHeaderStyles );

    Feb

    1

    Feathers3 "Tool-tips" 一些备注

    • 0 Comments
    • Flash Platform

    Tool-tips (提示功能)最常见的情况是在桌面开发的应用中,当鼠标悬停在某个 UI 按钮上面时,会出现一个提示文本。Feathers 也可提供了这样的功能,通过 ToolTipManager 可以方便的实现。(虽然移动开发也能使用,但移动设备因为没有鼠标指针,所以一般不会用这样的功能,就算用了在一般情况下也是看不到提示的)。

    启用 Tool-Tip Manager:

    要启用提示功能,应用首次启动时只需要一行代码:

    ToolTipManager.setEnabledForStage( this.stage, true );

    然后只需要设置组件的 toolTip 属性即可。如果开发的是一个桌面 AIR 程序,具有多个窗口,每个窗口都有一个独立的舞台对象,所以需要为每个应用窗口单独调用 setEnabledForStage() 方法。  

    var button:Button = new Button();
    button.label = "Click Me";
    button.toolTip = "Some useful information";

    所有的 Feathers 组件都有一个 toolTip 属性。

    Feb

    1

    Feathers 提供了拖放管理器(DragDropManager )提供拖放功能(Drag 与 Drop 功能, 也被简称为 “D&D” 功能,如果有使用过 Flex 的 D&D 功能,应该会很熟悉基本流程)。基本流程如下:

    1、首先需要在对应的对象上实现 IDragSource 与 IDropTarget 接口。

    2、调用 DragDropManager.startDrag() 方法:

    传入第一个参数是 IDragSource 对象。

    第二个参数是启动拖动操作的 Touch 对象。

    第三个参数是 DragData 对象,它存储正在拖动的数据,可以指定数据格式,用于指定不同的目标可以接受不同的数据类型。

    3、当被拖动的对象经过 IDropTarget 对象时,IDropTarget 对象会派发 DragDropEvent.DRAG_ENTER 事件时(DragDropManager 会自动派发这个事件,开发者只需要侦听这个事件就可以),DragData 包含了目标对象可以接受的数据格式,会调用 DragDropManager.acceptDrag() 方法。

    4、如果用户在 IDropTarget 对象上面有释放操作(比如停止触摸或释放鼠标),IDropTarget 对象会派发 DragDropEvent.DRAG_DROP 事件,如果正是需要的目标对象,需要在侦听器中处理释放(Drop)操作。

    5、无论释放操作是否在需要的目标对象上,IDragSource 对象都会派发 DragDropEvent.DRAG_COMPLETE 事件,事件对象的 isDropped 属性是会指示出释放操作是否成功。如果数据需要在释放操作后被删除,就可以在侦听器中处理,检查 isDropped 属性是否是成功的接受了释放对象,还是取消了。

    当在调用 DragDropManager.startDrag() 方法时,可以使用一个具体的图像作为拖动数据的“代理显示”。在拖动行为过程中这个图像会跟随着手指或鼠标移动。

    数据格式类似是在拖动对象与目标对象之间的一种契约协议,可能是代理显示的图像,也可能是纯粹的数据项,比如 List 对象中的项数据。如果只是简单的拖动一个显示对象(没有任何其它数据关联),开发者可以将显示对象作为拖动“数据”,类似代码:

    var dragData:DragData = new DragData();
    dragData.setDataForFormat("display-object-drag-format", theDisplayObject);

    可以使用任意的字符串“display-object-drag-format”,只需要拖动源与释放目标能相互识别即可:

    在  DragDropEvent.DRAG_ENTER 事件中,检测是否可以接受被拖动的对象:

    function(event:DragDropEvent, dragData:DragData):void
    {
        if(dragData.hasDataForFormat("display-object-drag-format"))
        {
            DragDropManager.acceptDrag(this);
        }
    }

    在 DragDropEvent.DRAG_DROP 事件侦听器中,使用 dragData.getDataForFormat() 方法来检索显示对象或其它数据。

    Jan

    30

    Feathers “pop-ups” 一些备注

    • 0 Comments
    • Flash Platform

    Feathers 包含了一个弹出窗口管理器(PopUpManager),管理 “pop-ups” (姑且称为它“弹出窗口”吧……,但在 pop-ups 的内容并不一定真的会是窗口……)内容。

    弹出窗口管理器允许开发者将弹出窗口内容置于所有其它 Starling 内容上面,并且提供了一些选项,比如模态化窗口或屏幕居中等功能。开发者还可以自定义弹出窗口的行为,比如弹出窗口内容的交互功能与显示列表中的位置等。

    假如焦点管理器(focus management)被启用时弹出窗口是一个模态化窗口,焦点管理器会为模态化窗口单独给出一个焦点管理器,以便防止模态化窗口下面的内容获得焦点。

    添加 pop-ups:

    使用 PopUpManager.addPopUp() 方法,可以将显示对象作为弹出窗口内容添加,必须先创建显示对象,如:

    var popUp:Image = new Image( texture );
    PopUpManager.addPopUp( popUp, true, true );

    第一个参数是弹出窗口内容,可以是任何 Starling 显示对象。

    第二个参数决定是否为模态化窗口(isModal)。

    第三个参数决定弹出窗口是否应该在舞台居中显示(isCentered)。如果舞台或弹出窗口尺寸发生变化,它会持续居中。

    第二和第三个参数是可选的。 如果省略,弹出窗口将是模态化窗口,并居中显示。 

    第四个参数也是可选的。允许开发者为模态化窗口传递自定义工厂方法用于设置“覆盖叠加”行为(指叠加模态化窗口下面的内容)。默认情况下,PopUpManager.overlayFactory 用于创建全局性的覆盖叠加行为,但也可以单独为某个弹出窗口设置覆盖叠加行为。

    移除 pop-ups:

    有两种方法可以移除弹出窗口。第一种方法是调用 PopUpManager.removePopUp() 方法。

    PopUpManager.removePopUp( popUp, true );

    第一个窗口是要移除的弹出窗口对象,如果传入的不是一个弹出窗口(pop-up)对象,就会产生运行时异常。第二个参数决定是否销毁对象(dispose)。

    也可以使用标准的 removeFromParent() 方法:

    popUp.removeFromParent( true );

    PopUpManager 会自动检测被移除的弹出窗口,如果是模态化窗口,“覆盖叠加”层也同时会被移除。

    居中 pop-ups:

    有两种方法可以让弹出窗口居中。

    第一种方法就是 PopUpManager.addPopUp() 方法的第三个参数设为 true。使用方法方法会让弹出窗口立即居中,并且会在舞台或窗口对象重置大小时持续居中。如果弹出窗口是一个 Feathers 组件,弹出窗口管理器(pop-up manager)就会在组件重置大小时让组件重新居中。如果普通的 Starling 显示对象则不行(普通的 Starling 显示对象在修改尺寸时并不会派发对应的事件)。

    第二种方法就是纯粹的调用 PopUpManager.centerPopUp() 方法,每调用一次就会执行居中算法一次。

    自定义 PopUpManager:

    通过定制 PopUpManager.overlayFactory,开发者可以更改模态化窗口的“覆盖叠加”行为与外观。默认情况下,全局的模态化窗口的叠加层是一个完全透明的 Quad 对象。可以自定义全局的“覆盖叠加层”:

    PopUpManager.overlayFactory = function():DisplayObject
    {
        var quad:Quad = new Quad(100100, 0x000000);
        quad.alpha = 0.75;
        return quad;
    };

    可以为单独的弹出窗口对象设置“覆盖叠加”行为:

    PopUpManager.addPopUp( popUp, true, true, function():DisplayObject
    {
        var quad:Quad = new Quad(100100, 0x000000);
        quad.alpha = 0.75;
        return quad;
    });

    开发者可以自定义 PopUpManager 的 root 属性,这是弹出窗口的根容器对象,默认情况下,PopUpManager 会直接将所有弹出窗口对象直接添加到 Starling 的 stage 对象。

    var popUpContainer:Sprite = new Sprite();
    this.stage.addChild( popUpContainer );
    PopUpManager.root = popUpContainer;

    如上代码,可以将所有弹出窗口对象都添加到 popUpContainer 容器中,这样可以确保弹出对象管理器的其它内容总是出现在所有羽毛内容的顶部(包括弹出对象)。

    Jan

    29

    在桌面开发时有一种常见的交互功能,就是通过键盘的 Tab 键切换获得焦点的对象,甚至通过键盘来执行按钮与滑块类的操作。Feathers 通过 FocusManager 类提供完全可选的焦点管理功能。一般来说,只应在桌面应用中启用焦点管理。 某些移动组件并未针对焦点管理进行优化。

    启用焦点管理:

    要使用焦点管理器功能,启动应用程序时只需要一行代码,然后用户就可以使用 Tab 键或 Shit + Tab 键在组件之间导航了。样例代码:

    FocusManager.setEnabledForStage( this.stage, true );

    如果开发的是一个桌面 AIR 程序拥有多个窗口,每个窗口有一个独立的舞台 Stage 对象,所以需要通过 setEnabledForStage() 方法为每个窗口单独设置一边。

    程序化的设置焦点:

    var focusManager:IFocusManager = FocusManager.getFocusManagerForStage( this.stage );
    focusManager.focus = button;

    这就好像是在 IFocusManager 实现类的对象上设置 focus 属性一样简单。

    要清除焦点,请将此属性设置为null:

    var focusManager:IFocusManager = FocusManager.getFocusManagerForStage( this.stage );
    focusManager.focus = null;

    自定义焦点顺序:

    默认情况下,在 Starling 世界里,通过键盘更改焦点对象时,是按显示列表中的顺序更改的。使用 getChildIndex() 方法和其它标准显示列表的 API,焦点管理器将以相对直观的顺序搜索显示列表,以找到可以接收焦点的下一个(或上一个)对象。

    如果焦点在转移的过程中与预期的效果不一样,可以通过 nextTabFocus 和 previousTabFocus 属性进行设置:

    var button1:Button = new Button();
    this.addChild( button1 );

    var button2:Button = new Button();
    this.addChild( button2 );

    button1.nextTabFocus = button2;
    button2.previousTabFocus = button1;

    焦点和弹出窗口:

    焦点管理器和弹出窗口管理器(pop-up manager)彼此知道如何沟通:

    a、如果弹出窗口是一个模态化窗口,会创建一个新的焦点管理器,这个新的焦点管理器会获得对键盘焦点的独占控制,所以模态化窗口口下面的内容都将无法接收焦点,直接到模态化窗口关闭。

    b、如果场景中同时有多个模态化窗口弹出,那么对应的会有更多的焦点管理器会被创建,并被添加到一个堆栈中,以确保最上面的模态化窗口会阻止所有下面内容的焦点。

    c、如果弹出窗口不是模态,则当前的焦点管理器将保持活动,并且一切都将能够接收焦点,包括弹出窗口和弹出窗口下面的所有内容。

    Jan

    29

    Feathers TextArea 一些备注

    • 0 Comments
    • Flash Platform

    TextArea 在备注文本编辑器资料时基本已经全部备注,其它的基本属性与功能(一些自动化相关的功能与皮肤样式等功能)也与 TextInput 组件类似。只是它是一个支持多行编辑功能的文本组件,而且文本框内的文本格式(字体样式)是需要一致的。

    TextArea 支持特殊的文本编辑器,需要实现 ITextEditorViewPort 接口。 默认的 TextArea 类的文本编辑器使用的是 TextFieldTextEditorViewPort 类(类似于 TextFieldTextEditor),它是通过 flash.text.TextField 来进行渲染的,因为传统的 TextField 是在原生舞台上,所以 skipUnchangedFrames 属性很可能会被禁用等。

    关于 skipUnchangedFrames 属性被禁用的资料请参看《skipUnchangedFrames 属性局限性》。

    另外就是它是带有滚动条的组件,滚动条的显示模式、交互功能、滚动策略与其它带有滚动条组件的备注资料是一致的,略。

    Jan

    29

    Feathers3 TextInput 一些备注

    • 0 Comments
    • Flash Platform

    TextInput 在备注文本编辑器资料时基本已经全部备注,只是 TextInput 除了文本编辑器部份外,还包含了一些自动化相关的功能与皮肤样式等功能。

    比如支持 prompt 功能:

    input.prompt = "Password";

    比如支持设置焦点与选择:

    input.setFocus();//程序化的获得焦点
    input.selectRange(0, input.text.length);//程序化的选择文本

    如果只是想简单的通过程序化的方式设置光标的位置,可以省略 selectRange()  第二参数:

    input.selectRange(0);

    TextInput 支持大量的类似 FLEX 框架中 TextInput 组件事件,如 Event.CHANGE、FeathersEventType.FOCUS_IN、FeathersEventType.FOCUS_OUT、FeathersEventType.ENTER 等事件。

    a、某些移动平台上 TextInput 组件可能并不会派发 FeathersEventType.ENTER 事件,具体取决于某些属性的值。这可能包括一些平台的默认值! 如果遇到此类问题,需要参考具体的“文本编辑器”的API文档,了解问题原因的限制和要求的完整详情。

    b、既便没有启用焦点管理器,TextInput 也会派发 FeathersEventType.FOCUS_IN、FeathersEventType.FOCUS_OUT 事件。

    maxChars 属性可以限制最大的输入字符数量;restrict 可以限制输入的字符。

    TextInput 可以设置多个状态的字体样式,如:fontStyles、disabledFontStyles、promptFontStyles、promptDisabledFontStyles 等。

    甚至可以自定义用户每个输入状态的字体样式,如:

    input.setFontStylesForState( TextInputState.ERROR,new TextFormat( "Helvetica"20, 0xcc0000 ) );

    当 TextInput  显示 errorString 属性时,会自动进入 TextInputState.ERROR 状态设置的文本样式。

    如果没有为某个状态设置字体样式,那么就会显示为默认的 fontStyles,比如一般我们没有设置 TextInputState.FOCUSED 状态的字体样式,所以显示的就是默认的 fontStyles。

    但是当 TextInput 获得焦点的时候,我们有可能会更改它的背景纹理。可以通过 setSkinForState() 方法实现,比如:

    var disabledSkin:ImageSkin = new ImageSkin( disabledTexture );
    input.scale9Grid = new Rectangle( 42210 );
    input.setSkinForState( TextInputState.DISABLED, disabledSkin );

    可以为 TextInput 添加一个图标(icon)。 可以为每个文本输入的状态定制图标(就像背景皮肤一样),比如,传递一个 starling.display.Image 对象:

    input.defaultIcon = new Image( iconTexture );

    如果只是简单的这样设置,这个默认的图标(defaultIcon)会在每个不同的状态都显示,如果想为单独的状态设置不同的图标,可以通过 setIconForState() 方法实现。

    TextInput 有一些常见的布局属性,如 paddingTop、paddingRight、paddingBottom、paddingLeft、padding 等。

    另一个比较有用的与布局有关的属性是 typicalText 。默认情况下,TextInput 的尺寸不会以输入的文本为尺寸进行计算,而是根据背景皮肤,填充和其他布局属性进行计算出来的。但有时候我们会需要根据文本的内容来显示对应尺寸的 TextInput ,比如一个 NumericStepper 组件,根据最大的可能的字符串来显示文本区域的尺寸可能是最合适的。